Create an ABAP Core Data Services (CDS) View in ABAP On-Premise

1. Create a new package for this tutorial, by choosing New > ABAP Package.

   

2. Enter the following then follow the wizard, choosing a new transport request:

• Name: Z_ENHANCE_CDS_XXX

• Description Enhance CDS Tutorial 2020

  

  

1. In your package, create a CDS view entity. Select the package, then choose New > Other from the context menu, then choose Data Definition.

   

2. Add the following:

   • Name: Z_I_TRAVEL_R_XXX
   • Description: Travel Model View Entity - Read Only
   • Referenced object: /DMO/I_TRAVEL_U

   Your CDS view is a read-only view. It is based on the business object (BO) view, /DMO/I_TRAVEL_U.

3. Choose or create a transport request, then choose Next. Do not choose Finish.

4. Choose Use template then choose Define View Entity.

   

5. Finally, choose Finish.

Your CDS entity appears in a new editor, with the elements (fields and associations) from the referenced data object, ``, already inserted. Ignore the error for now.

1. You will see 2 errors - at BookingFee and TotalPrice. Add the following annotations:

   CDS Copy

   @Semantics.amount.currencyCode: 'CurrencyCode'
   BookingFee,
   
   @Semantics.amount.currencyCode: 'CurrencyCode'
   TotalPrice,

2. Format, save, and activate your code by choosing Shift+F1, Ctrl+S, Ctrl+F3. It should look like this:

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Travel Model View Entity - Read Only'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}

define view entity Z_I_TRAVEL_R_XXX
  as select from /DMO/I_Travel_U as Travel

{
  key TravelID,
      AgencyID,
      CustomerID,
      BeginDate,
      EndDate,

      @Semantics.amount.currencyCode: 'CurrencyCode'
      BookingFee,

      @Semantics.amount.currencyCode: 'CurrencyCode'
      TotalPrice,

      CurrencyCode,
      Memo,
      Status,
      LastChangedAt,

      /* Associations */
      _Agency,
      _Booking,
      _Currency,
      _Customer,
      _TravelStatus
}

If you define currency amounts and currency codes semantically, then the system will apply specific rules to handle these fields appropriately. For example, in this tutorial, if you define TotalPrice as a currency amount, then the system will add the appropriate currency to the TotalPrice column automatically. There is no need to display CurrencyCode as a separate column.

1. Click anywhere in the editor and choose Open With > Data Preview from the context menu.

   

2. The Data Preview is displayed in a new tab. You can investigate the data, by filtering, specifying the number of rows, and so on. The values in LastChangedAt are not user-friendly, but you solve that by providing a Fiori elements preview in the next step.

   

You will now expose the CDS entity as a business service. This will allow you to preview your changes in Fiori elements preview.

A business service consists of a service definition and a service binding.

You use a service definition to define which data is to be exposed (with the required granularity) as a Business Service.

You then use the service binding to bind a service definition to a client-server communication protocol such as OData. This allows you to provide several bindings for the same definition, e.g. to expose the service to a UI, and to an A2X provider.

For more information, see:

• SAP Help Portal: Creating a Service Definition

• SAP Help Portal: Creating a Service Binding

1. First, create the service definition, by selecting your CDS entity and choosing New > Service Definition from the context menu.

   

2. Choose a name and description:

   • Z_EXPOSE_TRAVEL_XXX
   • Service exposes Travel data

   

3. Choose the transport request; choose Next.

4. Use the selected template; choose Finish. The name of your custom entity is inserted automatically.

   

5. To make the service definition more readable, add an alias to the expose statement:

   CDS Copy

   expose Z_C_TRAVELS_XXX as Travels;

6. Format, save, and activate ( Shift+F1, Ctrl+S, Ctrl+F3 ) the service definition.

1. Select your service definition, then choose Service Binding from the context menu, then choose Next.

   

2. Choose:

   • Name = Z_BIND_TRAVEL_XXX

   • Description = Service binding for Travel data

   • Binding Type = ODATA V2 (UI…)

   • Service Definition = Z_EXPOSE_TRAVEL_XXX

     

3. Choose the transport request; choose Finish.

The service binding automatically references the service definition and thus the exposed custom entity.

1. In the editor that appears, choose Activate.

   

2. You can now see the Service URL and Entity Set.

   

3. To open the Service Document (XML) in your browser, choose Service URL.

   

   

4. In the browser, you can also see the Metadata Document of the Business Service by adding $metadata to the URL: `/sap/opu/odata/sap/Z_BIND_TRAVEL_XXX/$metadata`.

   

1. Select the entity set and choose Preview.

   

2. Log in using your ABAP Environment user and password; the Fiori Elements preview appears.

3. By default, no columns are selected. To see the data, choose Settings, then choose Select All.

   

   

4. Display the data by choosing Go.

   

1. It would be nice if at least some fields were displayed immediately for the user. To do this, simply add the following annotation to the relevant fields in Z_I_TRAVEL_R_XXX. The start of your CDS entity will then look like this.

   BookingFee is not automatically displayed. The numbers for each field are relative to the other fields and are responsive - they do not refer to a specific pixel position or similar. For larger entities, you can specify HIGH,MEDIUM, or LOW, so that less important fields are automatically hidden on a smaller screen, such as a mobile phone.

   CDS Copy

   @UI           : {
   lineItem      : [{position: 10, importance: #HIGH}]
   }
   key TravelID;
   
   @UI           : {
         lineItem      : [{position: 15, importance: #HIGH}]
         }
   AgencyID,
   
   @UI           : {
         lineItem      : [{position: 20, importance: #HIGH}]
         }
   CustomerID,
   
   @UI           : {
         lineItem      : [{position: 30, importance: #HIGH}]
         }
   BeginDate,
   
   @UI           : {
         lineItem      : [{position: 40, importance: #HIGH}]
         }
   EndDate,
   
   BookingFee,
   
   @UI           : {
         lineItem      : [{position: 50, importance: #HIGH}]
         }
   TotalPrice,

   Show all 31 lines Show less

2. If you now refresh your Fiori Elements preview, you will notice that you do not have to choose the fields; you simply have to choose Go.

At present, you only have minimal annotations. As you add more, your CDS entity will start to get cluttered. So you should extract your UI annotations to a separate object, a metadata extensions object, as follows:

1. First add the annotation @Metadata.allowExtensions: true to your CDS entity.

2. Then, click anywhere in the editor, then choose Source Code > Extract Metadata Extension from the context menu.

   

3. Enter a name and description for your metadata extension object, clearly similar to your CDS entity name, and choose Next:

   • Z_TRAVEL_METADATA_XXX
   • Metadata for Z_I_TRAVEL_R_XXX

4. Accept the transport request, choose Next, select all elements, then choose Finish.

   

5. You will get an error, because you have not yet assigned the metadata extension to a layer. Since you are in sandbox mode, enter the value #CORE using auto-complete ( Ctrl+Space ).

   

   Layers allow customers or partners, for example, to enhance the metadata without modifying the CDS entity. You can also add industry- or country-specific enhancements.

   The metadata extensions are evaluated in a specific order. For more information, see Annotation Propagation.

6. Format, save, and activate ( Shift+F1, Ctrl+S, Ctrl+F3 ).

If you define currency amounts and currency codes semantically, then the system will apply specific rules to handle these fields appropriately. For example, in this tutorial, if you define TotalPrice as a currency amount, then the system will add the appropriate currency to the TotalPrice column automatically. There is no need to display CurrencyCode as a separate column.

1. To do this, add the following two annotations to your CDS entity:

   CDS Copy

   
   @Semantics.amount.currencyCode: 'CurrencyCode'        
   TotalPrice,
   
   @Semantics.currencyCode
   CurrencyCode,

2. Format, save, and activate ( Shift+F1, Ctrl+S, Ctrl+F3 ).

3. If you refresh the Fiori Elements preview, the Total Price column now looks like this.

   

You will now add a fuzzy search capability.

1. First, add the search annotation to your CDS entity:

   CDS Copy

   @Search.searchable: true

2. Then add the following two annotations to the field you want to search, in this case Memo:

   CDS Copy

   @Search.defaultSearchElement: true
   @Search.fuzzinessThreshold: 0.90

3. For convenience, add the following annotation to the metadata extension object, so that the Memo field appears by default in the preview, then format, save, and activate ( Shift+F1, Ctrl+S, Ctrl+F3 ):

   CDS Copy

   @UI: { lineItem      : [{position: 60, importance: #HIGH}]
         }
   Memo;

4. Refresh the Fiori elements preview in your browser.

5. There is a new Search input field.

   

6. Enter the search text Miami. The app only displays trips to Miami (to date, eleven trips).

   

7. Optional: You can test the fuzziness threshold by changing the value to 0.70. After you save and activate, the app will now show trips to Miami and trips involving Matthias. (You may need to empty the cache.)

   

As well as search fields, you can filter the list using an input field. In the next tutorial, you will provide input value help for these fields.

1. Add the selectionField annotation to the field TravelID in your metadata extension file, so that the whole UI annotation looks like this:

   CDS Copy

   @UI           : {
         lineItem      : [{position: 10, importance: #HIGH}],
         selectionField: [{position: 10 }]
         }
   TravelID;

   ata-lang=cds>

   CDS Copy

   @Metadata.layer: #CORE
   annotate view Z_I_TRAVEL_R_XXX with
   {
   
   @UI           : {
         lineItem      : [{position: 15, importance: #HIGH}],
         selectionField: [{position: 15 }]
         }
   AgencyID;
   
   @UI           : {
         lineItem      : [{position: 20, importance: #HIGH}],
         selectionField: [{position: 20 }]
         }
   CustomerID;
   
   @UI           : {
         lineItem      : [{position: 10, importance: #HIGH}],
         selectionField: [{position: 10 }]
         }
   TravelID;
   
   @UI           : {
         lineItem      : [{position: 30, importance: #HIGH}],
         selectionField: [{position: 30 }]
         }
   BeginDate;
   
   @UI           : {
         lineItem      : [{position: 40, importance: #HIGH}],
         selectionField: [{position: 40 }]
         }
   EndDate;
   
   @UI           : {
         lineItem      : [{position: 50, importance: #HIGH}]
         }
   TotalPrice;
   
   @UI           : {
         lineItem      : [{position: 50, importance: #HIGH}]
         }
   Memo;
   
   @UI           : {
       lineItem      : [{position: 60, importance: #HIGH}],
       selectionField: [{position: 60 }]
       }
   Status;
   
   }

   Show all 51 lines Show less
   Done